//****************************************************************************************//
//
//      MISSION:  Mc2_06
//		Units That guard important vehicles in a convoy.
//		
//
//****************************************************************************************//

fsm mc2_06_1_1grd;

	var

//**************ORIGINAL******************
		static WorldPosition		startPosition;
		static PatrolState		startPatrolState;
		static PatrolPath			startPatrolPath;
		static boolean			willRequestHelp;
		static real				lastHelpRequestTime;
		static real				helpRequestFrequency;
		static real				attackerHelpRadius;
		static real				defenderHelpRadius;
		static integer			AttackStateHandle;
		static boolean			poweredDown;
		static integer			numFunctionalWeapons;
		static integer[20]		weaponList;
		
		static integer				guardCharge;
		static WorldPosition	guardChargePos;
		static integer				guardChargeStatus;

//**************NEW***********************
		static integer				Guard1st;
		static integer				Guard2nd;
		static integer				Guard3rd;

//****************************************************************************************

function init;

    code

//**************ORIGINAL******************
		setDebugWindow(-1, -1);

		//---------------------------
		// Grab his start position...
		getObjectPosition(-1, startPosition);

		//-------------------
		// Look for movers...
		setTargetPriority(0, TARGET_PRIORITY_CURTARGET, -1, 400, CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED);
		setTargetPriority(1, TARGET_PRIORITY_MOVER, 0, 500, CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED);
		setTargetPriority(2, TARGET_PRIORITY_NONE, 0, 0, 0);

		AttackStateHandle = getStateHandle("attack");

//**************NEW***********************
		//CvA_Patrol_Triggered = FALSE; //LT, used to check Patrol has been triggered
		//CvA_Patrol_End_Triggered = FALSE;  //LT, used to check when NCV patrol ends

		//-------------------------------------------
		// Setup the Patrol here...
		//XL startBase1PatrolState Start

				//Get off edge of map
		startPatrolState[0] = PATROL_TYPE_LINEAR;
		startPatrolState[1] = 4;    //?num points
		startPatrolState[2] = 1;    //?num cycles
		startPatrolState[3] = PATROL_DIRECTION_FORWARD;
		startPatrolState[4] = -1;    //reset cur point
		startPatrolState[5] = -1;    //reset cur cycle
		startPatrolState[6] = 0 + CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL + CONTACT_CRITERIA_NOT_DISABLED;

		startPatrolPath[0, 0] = startPosition[0];
		startPatrolPath[0, 1] = startPosition[1];
		startPatrolPath[1, 0] = startPosition[0] + 13;
		startPatrolPath[1, 1] = startPosition[1] - 213.333;
		startPatrolPath[2, 0] = startPosition[0] + 13;
		startPatrolPath[2, 1] = startPosition[1] - 597.333;
		startPatrolPath[3, 0] = startPosition[0] + 13;
		startPatrolPath[3, 1] = startPosition[1] - 1109.333;
		

		//XLs startBase1PatrolPath end
		
//**************ORIGINAL******************

		willRequestHelp = true; //?true or false
		helpRequestFrequency = 20.0; //?in secs
		attackerHelpRadius = 200; //?in meters
		defenderHelpRadius = 225; //?in meters
		lastHelpRequestTime = -100.0;

 //*************addvar****************** 					

	Guard1st = 704;
	Guard2nd = 705;
	Guard3rd = 709;
	
	guardCharge = 0;
	guardChargeStatus = 0;

 //*************endaddvar******************

endfunction;


//----------------------------------------------------------------------------------------

function setWillRequestHelp (boolean setting);

	code

		if (setting and (not willRequestHelp)) then
			lastHelpRequestTime = 0.0;
		endif;
		willRequestHelp = setting;

endfunction;

//----------------------------------------------------------------------------------------

function update : integer;

	var

		boolean		processingPilotEvents;
		boolean		thinking;
		integer		pilotEventID;
		integer		pilotState;
		integer[20]		pilotEventParams;
		integer		curTarget;
		real			curTime;
		real[3]		myPos;
		real[3]		attackerPos;
		real			distanceToAttacker;
		integer		curStateHandle;


	code

		curTime = getTime;

//**************NEW***********************
		
//**************End New******************


		//-----------------------------------
		//
		curStateHandle = getCurrentStateHandle;


		//--------------------------------------------------
		// Process the pilot events since the last update...
		numFunctionalWeapons = getWeapons(weaponList, 1);
		if (numFunctionalWeapons == 0) then
			trans noWeapons;
		endif;

		processingPilotEvents = TRUE;
		while (processingPilotEvents) do
			pilotEventID = getNextPilotEvent(pilotEventParams);
			if (pilotEventID == PILOT_EVENT_NONE) then
				processingPilotEvents = FALSE;
			else
				switch (pilotEventID)
					case PILOT_EVENT_TARGETED:
						curTarget = getTarget(-1);
						if (lastHelpRequestTime < (curTime - helpRequestFrequency)) then
							lastHelpRequestTime = curTime;
							if (willRequestHelp) then
								//distanceToAttacker = distanceToObject(-1, pilotEventParams[0]);
								getObjectPosition(pilotEventParams[0], attackerPos);
								getObjectPosition(-1, myPos);
								requestHelp(pilotEventParams[0], myPos, attackerHelpRadius, attackerPos, defenderHelpRadius, 1);
							endif;
						endif;
						numFunctionalWeapons = getWeapons(weaponList, 0);
						if (curStateHandle <> AttackStateHandle) then
							if ((numFunctionalWeapons > 0) and (curTarget == 0)) then
								coreAttack(pilotEventParams[0], TACORDER_PARAM_PURSUE);
								setState(AttackStateHandle);
							endif;
						endif;
						endcase;
					case PILOT_EVENT_ATTACK_ORDER:
						curTarget = getTarget(-1);
						if (curStateHandle <> AttackStateHandle) then
							if ((numFunctionalWeapons > 0) and (curTarget == 0))then
								coreAttack(pilotEventParams[0], TACORDER_PARAM_PURSUE);
								setState(AttackStateHandle);
							endif;
						endif;
						endcase;
					case PILOT_EVENT_FIRED_WEAPON:
						endcase;
				endswitch;
			endif;
		endwhile;

		return(0);

endfunction;

//----------------------------------------------------------------------------------------

state noWeapons;

	code

		setDebugString(-1, 3, "   NO WEAPONS ");
		if (objectClass(-1) == 2) then
			coreEject;
		else
			corePower(false);
		endif;
		
endstate;


//----------------------------------------------------------------------------------------

state Base1Escort;

	var

	code

		update;
		setDebugString(-1, 3, "   ESCORT    ");
		//coreRun = True;
		//select my guard charge
		if (guardCharge <> 0) then
			guardChargeStatus = objectStatus(guardCharge);
			if ((guardChargeStatus == 1) or (guardChargeStatus == 2)) then
				guardCharge = 0;
			endif;
		endif;

		if (guardCharge == 0) then
			if ((objectStatus(Guard1st) <> OBJ_STATUS_DISABLED) and (objectStatus(Guard1st) <> OBJ_STATUS_DESTROYED)) and (objectTeam(Guard1st) == obj_team_2) then
				guardCharge = Guard1st;	
			else
				if ((objectStatus(Guard2nd) <> OBJ_STATUS_DISABLED) and (objectStatus(Guard2nd) <> OBJ_STATUS_DESTROYED)) and (objectTeam(Guard2nd) == obj_team_2) then
				guardCharge = Guard2nd;
				else
					if ((objectStatus(Guard3rd) <> OBJ_STATUS_DISABLED) and (objectStatus(Guard3rd) <> OBJ_STATUS_DESTROYED)) and (objectTeam(Guard3rd) == obj_team_2) then
						guardCharge = Guard3rd;setDebugString(-1, 3, " WAIT    ");
					else
						trans Attack;
					endif;
				endif;
			endif;
		endif;

		if (guardCharge == 0) then
			getObjectPosition(-1, guardChargePos);
			setMoveArea(guardChargePos, -1.0);
			coreGuard(guardChargePos, -1, AttackStateHandle);
		else
			getObjectPosition(guardCharge, guardChargePos);
			setMoveArea(guardChargePos, 100.0);
			coreEscort(guardCharge, 40.0, 135.0, -1);
		endif;


endstate;

//----------------------------------------------------------------------------------------
//----------------------------------------------------------------------------------------
//----------------------------------------------------------------------------------------

state attack;

	var

		integer		tacticState;

	code


		update;
		setDebugString(-1, 3, " ATTACK    ");
//		coreAttackTactic(0, TACORDER_PARAM_NONE, TACTIC_RIGHT_FLANK, tacticState);
		coreAttack(0, TACORDER_PARAM_PURSUE);
		resetOrders(1);
		
endstate;

//----------------------------------------------------------------------------------------

state start;

	code
	
	coreWait(10, -1, -1);
	//coreRun = True;
	setDebugString(-1, 3, " WAIT    ");
	patrol(startpatrolState, startPatrolPath);
				
		if (gametime <> 0) then
			trans Base1Escort;
		endif;
		
		
		update;
endstate;

//----------------------------------------------------------------------------------------

endfsm.

//****************************************************************************************