//****************************************************************************************//
// 
//		Ecounter 2   Vehicles Guarding the Base
//			
//
//      MISSION:  Mc2_2 Liao Palace
//		This will Guard it start location
//		if it detects the player it will attack.
//
//****************************************************************************************//

fsm mc2_22_EC2_Veh_Guard;

	var

		static WorldPosition		startPosition;
		static PatrolState		startPatrolState, palacePatrolState;
		static PatrolPath			startPatrolPath, palacePatrolPath;
		static boolean			willRequestHelp;
		static real				lastHelpRequestTime;
		static real				helpRequestFrequency;
		static real				attackerHelpRadius;
		static real				defenderHelpRadius;
		static integer			AttackStateHandle;

		static integer			numFunctionalWeapons;
		static integer[20]		weaponList;

		static boolean			goto_Palace;
		static boolean			baseAttack;

//****************************************************************************************

function init;

    code

		//setDebugWindow(-1, -1);

		//---------------------------
		// Grab his start position...
		getObjectPosition(-1, startPosition);

		//-------------------
		// Look for movers...
		setTargetPriority(0, TARGET_PRIORITY_CURTARGET, -1, 50, CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED);
		setTargetPriority(1, TARGET_PRIORITY_MOVER, 0, 300, CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED);
		setTargetPriority(2, TARGET_PRIORITY_NONE, 0, 0, 0);

		AttackStateHandle = getStateHandle("attack");
		baseAttack = False;
		goto_Palace = False;


		startPatrolState[0] = PATROL_TYPE_LINEAR;    
		startPatrolState[1] = 2;    //?num points
		startPatrolState[2] = -1;    //?num cycles
		startPatrolState[3] = PATROL_DIRECTION_FORWARD;    
		startPatrolState[4] = -1;    //reset cur point
		startPatrolState[5] = -1;    //reset cur cycle
		startPatrolState[6] = CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED;    
		startPatrolPath[0, 0] = 960.000;
		startPatrolPath[0, 1] = -4800.000;
		startPatrolPath[1, 0] = 490.667;
		startPatrolPath[1, 1] = -5525.333;


		palacePatrolState[0] = PATROL_TYPE_LINEAR;    
		palacePatrolState[1] = 2;    //?num points
		palacePatrolState[2] = 1;    //?num cycles
		palacePatrolState[3] = PATROL_DIRECTION_FORWARD;    
		palacePatrolState[4] = -1;    //reset cur point
		palacePatrolState[5] = -1;    //reset cur cycle
		palacePatrolState[6] = CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED;    
		palacePatrolPath[0, 0] = 4288.000;
		palacePatrolPath[0, 1] = 2410.667;
		palacePatrolPath[1, 0] = 4288.000;
		palacePatrolPath[1, 1] = 2410.667;



		willRequestHelp = true; //?true or false
		helpRequestFrequency = 20.0; //?in secs
		attackerHelpRadius = 200; //?in meters
		defenderHelpRadius = 225; //?in meters
		lastHelpRequestTime = -100.0;
						
endfunction;


//----------------------------------------------------------------------------------------

function setWillRequestHelp (boolean setting);

	code

		if (setting and (not willRequestHelp)) then
			lastHelpRequestTime = 0.0;
		endif;
		willRequestHelp = setting;

endfunction;

//----------------------------------------------------------------------------------------

function update : integer;

	var

		boolean		processingPilotEvents;
		boolean		thinking;
		integer		pilotEventID;
		integer		pilotState;
		integer[20]		pilotEventParams;
		integer		curTarget;
		real			curTime;
		real[3]		myPos;
		real[3]		attackerPos;
		real			distanceToAttacker;
		integer		curStateHandle;


	code

		//--------------------------------------------------
		// Check Time and Check Current State Handle
		curTime = getTime;
		curStateHandle = getCurrentStateHandle;
		//--------------------------------------------------


		//--------------------------------------------------
		//Check if I should head towards the Palace
		if (palaceBeenAttack) then
			if (NOT goto_Palace) then
				goto_Palace = True;
				//trans goToPalace;
			endif;
		endif;

		//--------------------------------------------------
		//Check if Base is under Attack
		if (baseUnderAttack) then
			if (NOT baseAttack) then
				baseAttack = True;
				trans goToPalace;
			endif;
		endif;

		//--------------------------------------------------
		// Process the pilot events since the last update...
		numFunctionalWeapons = getWeapons(weaponList, 1);
		if (numFunctionalWeapons == 0) then
			trans noWeapons;
		endif;

		processingPilotEvents = TRUE;
		while (processingPilotEvents) do
			pilotEventID = getNextPilotEvent(pilotEventParams);
			if (pilotEventID == PILOT_EVENT_NONE) then
				processingPilotEvents = FALSE;
			else
				switch (pilotEventID)
					case PILOT_EVENT_TARGETED:
						curTarget = getTarget(-1);
						if (lastHelpRequestTime < (curTime - helpRequestFrequency)) then
							lastHelpRequestTime = curTime;
							if (willRequestHelp) then
								//distanceToAttacker = distanceToObject(-1, pilotEventParams[0]);
								getObjectPosition(pilotEventParams[0], attackerPos);
								getObjectPosition(-1, myPos);
								requestHelp(pilotEventParams[0], myPos, attackerHelpRadius, attackerPos, defenderHelpRadius, 1);
							endif;
						endif;
						numFunctionalWeapons = getWeapons(weaponList, 0);
						if (curStateHandle <> AttackStateHandle) then
							if ((numFunctionalWeapons > 0) and (curTarget == 0)) then
								coreAttack(pilotEventParams[0], TACORDER_PARAM_PURSUE);
								setState(AttackStateHandle);
							endif;
						endif;
						endcase;
					case PILOT_EVENT_ATTACK_ORDER:
						curTarget = getTarget(-1);
						if (curStateHandle <> AttackStateHandle) then
							if ((numFunctionalWeapons > 0) and (curTarget == 0))then
								coreAttack(pilotEventParams[0], TACORDER_PARAM_PURSUE);
								setState(AttackStateHandle);
							endif;
						endif;
						endcase;
					case PILOT_EVENT_FIRED_WEAPON:
						endcase;
				endswitch;
			endif;
		endwhile;

		return(0);

endfunction;

//----------------------------------------------------------------------------------------

state noWeapons;

	code

		setDebugString(-1, 3, "   NO WEAPONS ");
		if (objectClass(-1) == 2) then
			coreEject;
		else
			corePower(false);
		endif;
		
endstate;

//----------------------------------------------------------------------------------------

state attack;
	var

		integer		tacticState;
	code

		baseUnderAttack = True;

		update;
		setDebugString(-1, 3, " ATTACK    ");
//		coreAttackTactic(0, TACORDER_PARAM_NONE, TACTIC_REAR, tacticState);
		coreAttack(0, TACORDER_PARAM_PURSUE);
		resetOrders(1);
		transBack;

endstate;


//----------------------------------------------------------------------------------------
state	goToPalace;

	code
		update;
		setDebugString(-1, 3, " GoPalace    ");	
		corePatrol(palacePatrolState, palacePatrolPath, attackStateHandle);
		trans guardPalace;

endstate;

//----------------------------------------------------------------------------------------
state guardPalace;

	var
		worldPosition		palaceGuard;

	code
		update;
		setDebugString(-1, 3, " GuardPalace    ");
		palaceGuard[0] = -1984.000;
		palaceGuard[1] = 2880.000;
		palaceGuard[2] = 0.0;
		setMoveArea(palaceGuard, 50.0);
		coreGuard (palaceGuard, -1,  attackStateHandle);
		resetOrders(1);
endstate;

//----------------------------------------------------------------------------------------
state BaseOnAlert;

	code

		setTargetPriority(0, TARGET_PRIORITY_CURTARGET, -1, 600, CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED);
		setTargetPriority(1, TARGET_PRIORITY_MOVER, 0, 400, CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED);


		update;
		setDebugString(-1, 3, "AlertPatrol     ");
		coreGuard (startPosition, -1,  attackStateHandle);
		resetOrders(1);
endstate;

//----------------------------------------------------------------------------------------

state start;

	code

		update;
		setDebugString(-1, 3, "StartPatrol1     ");
		coreGuard(startPosition, -1 , 0);
		resetOrders(1);
		trans Attack;
endstate;

//----------------------------------------------------------------------------------------

endfsm.

//****************************************************************************************