//****************************************************************************************//
//
//		Ecounter Town - Group of 1 Harasser & 1 Monsoon
//
//      MISSION:  Mc2_23
//		These Unit(s) PATROL the LAKESIDE
//		
//
//****************************************************************************************//

fsm mc2_23_Westside_patrol1;

	var

		static WorldPosition		startPosition;
		static PatrolState		startPatrolState;
		static PatrolPath			startPatrolPath;
		static boolean			willRequestHelp;
		static real				lastHelpRequestTime;
		static real				helpRequestFrequency;
		static real				attackerHelpRadius;
		static real				defenderHelpRadius;
		static integer			AttackStateHandle;

		static integer			numFunctionalWeapons;
		static integer[20]		weaponList;
		static boolean			Starport_Patrol_Check;
		static real				StarportTimerDelay;
		static boolean			StarportTimer_Check;
		static PatrolState		startPatrolToStarportState;
		static PatrolPath		startPatrolToStarportPath;
		static PatrolState		startStarportPatrolState;
		static PatrolPath		startStarportPatrolPath;
//****************************************************************************************

function init;

    code

		//setDebugWindow(-1, -1);

		//---------------------------
		// Grab his start position...
		getObjectPosition(-1, startPosition);

		//-------------------
		// Look for movers...
		setTargetPriority(0, TARGET_PRIORITY_CURTARGET, -1, 150, CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED);
		setTargetPriority(1, TARGET_PRIORITY_MOVER, 0, 250, CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED);
		setTargetPriority(2, TARGET_PRIORITY_NONE, 0, 0, 0);

		AttackStateHandle = getStateHandle("attack");
		Starport_Patrol_Check = FALSE; //LT, used to check Patrol has been triggered
		StarportTimer_Check = FALSE;


		startPatrolState[0] = PATROL_TYPE_LINEAR;
		startPatrolState[1] = 2;    //?num points
		startPatrolState[2] = -1;    //?num cycles
		startPatrolState[3] = PATROL_DIRECTION_FORWARD;
		startPatrolState[4] = -1;    //reset cur point
		startPatrolState[5] = -1;    //reset cur cycle
		startPatrolState[6] = CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED;
		startPatrolPath[0, 0] = -4928.000;
		startPatrolPath[0, 1] = 2880.000;
		startPatrolPath[1, 0] = -4800.000;
		startPatrolPath[1, 1] = 832.000;

		
		startPatrolToStarportState[0] = PATROL_TYPE_LINEAR;
		startPatrolToStarportState[1] = 3;    //?num points
		startPatrolToStarportState[2] = 1;    //?num cycles
		startPatrolToStarportState[3] = PATROL_DIRECTION_FORWARD;
		startPatrolToStarportState[4] = -1;    //reset cur point
		startPatrolToStarportState[5] = -1;    //reset cur cycle
		startPatrolToStarportState[6] = 0 + CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED;

		startPatrolToStarportPath[0, 0] = -7232.000;
		startPatrolToStarportPath[0, 1] = -832.000;
		startPatrolToStarportPath[1, 0] = -4288.000;
		startPatrolToStarportPath[1, 1] = -576.000;
		startPatrolToStarportPath[2, 0] = 448.000;
		startPatrolToStarportPath[2, 1] = -3776.000;
		
		startStarportPatrolState[0] = PATROL_TYPE_LINEAR;
		startStarportPatrolState[1] = 2;    //?num points
		startStarportPatrolState[2] = -1;    //?num cycles
		startStarportPatrolState[3] = PATROL_DIRECTION_FORWARD;
		startStarportPatrolState[4] = -1;    //reset cur point
		startStarportPatrolState[5] = -1;    //reset cur cycle
		startStarportPatrolState[6] = 0 + CONTACT_CRITERIA_ENEMY + CONTACT_CRITERIA_VISUAL_OR_SENSOR + CONTACT_CRITERIA_NOT_DISABLED;

		startStarportPatrolPath[0, 0] = 2453.333;
		startStarportPatrolPath[0, 1] = -2240.000;
		startStarportPatrolPath[1, 0] = 2453.333;
		startStarportPatrolPath[1, 1] = -5098.667;

		willRequestHelp = false; //?true or false
		helpRequestFrequency = 20.0; //?in secs
		attackerHelpRadius = 100; //?in meters
		defenderHelpRadius = 125; //?in meters
		lastHelpRequestTime = -100.0;
						
endfunction;


//----------------------------------------------------------------------------------------

function setWillRequestHelp (boolean setting);

	code

		if (setting and (not willRequestHelp)) then
			lastHelpRequestTime = 0.0;
		endif;
		willRequestHelp = setting;

endfunction;

//----------------------------------------------------------------------------------------

function update : integer;

	var

		boolean		processingPilotEvents;
		boolean		thinking;
		integer		pilotEventID;
		integer		pilotState;
		integer[20]		pilotEventParams;
		integer		curTarget;
		real			curTime;
		real[3]		myPos;
		real[3]		attackerPos;
		real			distanceToAttacker;
		integer		curStateHandle;


	code

		curTime = getTime;

		//-----------------------------------
		//
		curStateHandle = getCurrentStateHandle;
		
		if (Starport_Reinforcements_Trigger) then
			if (NOT Starport_Patrol_Check) then
				Starport_Patrol_Check = TRUE;
				StarportTimerDelay = getTime + 3; //Wait 10 secs before attacking
			else
				if ((getTime > StarportTimerDelay) AND (Not StarportTimer_Check)) then
						StarportTimer_Check = True;
						trans PatrolToStarport;
    		endif;
			endif;
		endif;

		//--------------------------------------------------
		// Process the pilot events since the last update...
		numFunctionalWeapons = getWeapons(weaponList, 1);
		if (numFunctionalWeapons == 0) then
			trans noWeapons;
		endif;

		processingPilotEvents = TRUE;
		while (processingPilotEvents) do
			pilotEventID = getNextPilotEvent(pilotEventParams);
			if (pilotEventID == PILOT_EVENT_NONE) then
				processingPilotEvents = FALSE;
			else
				switch (pilotEventID)
					case PILOT_EVENT_TARGETED:
						curTarget = getTarget(-1);
						if (lastHelpRequestTime < (curTime - helpRequestFrequency)) then
							lastHelpRequestTime = curTime;
							if (willRequestHelp) then
								//distanceToAttacker = distanceToObject(-1, pilotEventParams[0]);
								getObjectPosition(pilotEventParams[0], attackerPos);
								getObjectPosition(-1, myPos);
								requestHelp(pilotEventParams[0], myPos, attackerHelpRadius, attackerPos, defenderHelpRadius, 1);
							endif;
						endif;
						numFunctionalWeapons = getWeapons(weaponList, 0);
						if (curStateHandle <> AttackStateHandle) then
							if ((numFunctionalWeapons > 0) and (curTarget == 0)) then
								coreAttack(pilotEventParams[0], TACORDER_PARAM_PURSUE);
								setState(AttackStateHandle);
							endif;
						endif;
						endcase;
					case PILOT_EVENT_ATTACK_ORDER:
						curTarget = getTarget(-1);
						if (curStateHandle <> AttackStateHandle) then
							if ((numFunctionalWeapons > 0) and (curTarget == 0))then
								coreAttack(pilotEventParams[0], TACORDER_PARAM_PURSUE);
								setState(AttackStateHandle);
							endif;
						endif;
						endcase;
					case PILOT_EVENT_FIRED_WEAPON:
						endcase;
				endswitch;
			endif;
		endwhile;

		return(0);

endfunction;

//----------------------------------------------------------------------------------------

state noWeapons;

	code

		setDebugString(-1, 3, "   NO WEAPONS ");
		if (objectClass(-1) == 2) then
			coreEject;
		else
			corePower(false);
		endif;
		
endstate;

//----------------------------------------------------------------------------------------

state PatrolToStarport;

	code

		//coreRun = TRUE;
		update;
		setDebugString(-1, 3, "  PatrolToStarport     ");
		corePatrol(startPatrolToStarportState, startPatrolToStarportPath, AttackStateHandle);
		trans StarportPatrol;
		resetOrders(1);
endstate;

//----------------------------------------------------------------------------------------

state StarportPatrol;

	code

		//coreRun = FALSE;
		update;
		setDebugString(-1, 3, "  StarportPatrol     ");
		corePatrol(startStarportPatrolState, startStarportPatrolPath, AttackStateHandle);
		resetOrders(1);
endstate;

//----------------------------------------------------------------------------------------

state attack;

	var

		integer		tacticState;

	code

		update;
		setDebugString(-1, 3, " ATTACK    ");
		coreAttack(0, TACORDER_PARAM_STOP_AND_FIRE);
//		coreAttackTactic(0, TACORDER_PARAM_NONE, TACTIC_STOP_AND_ATTACK, tacticState);
//		coreAttack(0, TACORDER_PARAM_PURSUE);
		resetOrders(1);
		transBack;

endstate;

//----------------------------------------------------------------------------------------

state start;

	code

		update;
		setDebugString(-1, 3, "  StartPatrol1     ");
		corePatrol(startPatrolState, startPatrolPath, AttackStateHandle);
		resetOrders(1);
endstate;

//----------------------------------------------------------------------------------------

endfsm.

//****************************************************************************************